#!ipxe

# Some menu defaults
set menu-timeout 50000
set submenu-timeout ${menu-timeout}
isset ${menu-default} || set menu-default exit

:start
menu iPXE boot menu for 
item --gap --             ------------------------- Boot server selector ------------------------------
item --key l LDS      Boot to LDS
item --key W WDS      Boot to WDS
item --gap --             ------------------------- Advanced options -------------------------------
item shell                Drop to iPXE shell
item poweroff             Shutdown computer
item reboot               Reboot computer
item
item --key x exit         Exit iPXE and continue BIOS boot
choose --timeout ${menu-timeout} --default ${menu-default} selected || goto cancel
set menu-timeout 0
goto ${selected}

:cancel
echo You cancelled the menu, dropping you to a shell

:shell
echo Type 'exit' to get the back to the menu
shell
set menu-timeout 0
set submenu-timeout 0
goto start

:failed
echo Booting failed, dropping to shell
goto shell

:poweroff
poweroff

:reboot
reboot

:exit
exit

#Load LDS
:LDS
chain LDS.ipxe
boot

#Set DHCP user class to "wds" and start networkboot
:WDS
set user-class wds
autoboot || goto failed